configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Init autoconf
   4 AC_INIT(src/aubio.h)
   5
   6 dnl Package name and version
   7 PACKAGE=aubio
   8 . $srcdir/VERSION
   9 AUBIO_VERSION=${AUBIO_MAJOR_VERSION}.${AUBIO_MINOR_VERSION}.${AUBIO_PATCH_VERSION}${AUBIO_VERSION_STATUS}
  10 VERSION=${AUBIO_VERSION}
  11
  12 dnl Shared library version
  13 SHARED_VERSION_INFO=${LIBAUBIO_LT_CUR}:${LIBAUBIO_LT_REV}:${LIBAUBIO_LT_AGE}
  14 AC_SUBST(SHARED_VERSION_INFO)
  15
  16 dnl Init automake
  17 AM_INIT_AUTOMAKE(${PACKAGE}, ${VERSION})
  18
  19 dnl Maintainer mode
  20 AM_MAINTAINER_MODE
  21
  22 dnl Guess the host
  23 AC_CANONICAL_HOST
  24
  25 dnl Check for programs
  26 AC_PROG_CC
  27 AM_PROG_CC_C_O dnl compiling with per-target flag
  28 if test "$ac_cv_prog_cc" = "no" ; then
  29    AC_MSG_ERROR([*** No C compiler found !])
  30 fi
  31 AC_PROG_CXX
  32 AC_PROG_INSTALL
  33
  34 AUBIO_CFLAGS=
  35
  36 dnl Enable debugging (no)
  37 AC_ARG_ENABLE(debug,
  38   AC_HELP_STRING([--enable-debug],[compile in debug mode [[default=no]]]),
  39   with_debug="yes",
  40   with_debug="no")
  41 if test "$with_debug" = "yes"
  42 then
  43   AC_DEFINE(DEBUG,1,[Define to enable debug])
  44   AUBIO_CFLAGS="$AUBIO_CFLAGS -g"
  45 fi
  46
  47 dnl Enable full warnings (yes)
  48 AC_ARG_ENABLE(warnings,
  49   AC_HELP_STRING([--enable-warnings],[compile with all gcc warnings [[default=yes]]]),
  50   with_warnme="no",
  51   with_warnme="yes")
  52 if test "$with_warnme" = "yes"
  53 then
  54   dnl Check for -Wextra support to allow compilation on gcc <= 3.4
  55   AC_CACHE_CHECK([for -Wextra option to $CC], ac_cv_cc_wextra,
  56   [old_CFLAGS="$CFLAGS"
  57   CFLAGS="$CFLAGS -Wextra"
  58   AC_COMPILE_IFELSE([void foo (void) {}],
  59           ac_cv_cc_wextra=yes, ac_cv_cc_wextra=no)
  60   CFLAGS="$old_CFLAGS"
  61   ])
  62   if test "$ac_cv_cc_wextra" = "yes"
  63   then
  64     AUBIO_CFLAGS="$AUBIO_CFLAGS -Wall -Wextra"
  65   else
  66     AUBIO_CFLAGS="$AUBIO_CFLAGS -Wall"
  67   fi
  68 fi
  69
  70 dnl fail on compilation warnings
  71 AC_ARG_ENABLE(errorfail,
  72   AC_HELP_STRING([--enable-errorfail],[fail on compilation warnings [[default=no]]]),
  73   AUBIO_CFLAGS="$AUBIO_CFLAGS -Werror -Wmissing-prototypes -Wmissing-declarations -Wno-unused-parameter",
  74   with_errorfail="no")
  75
  76 dnl add gcov/lcov profiling and coverage flags
  77 AC_ARG_ENABLE(lcov,
  78   AC_HELP_STRING([--enable-lcov],[compile with gcov/lcov profiling flags [[default=no]]]),
  79   AUBIO_CFLAGS="$AUBIO_CFLAGS -fprofile-arcs -ftest-coverage",
  80   with_lcov="no")
  81
  82 dnl Check for libtool
  83 AC_LIBTOOL_DLOPEN
  84 dnl AC_DISABLE_STATIC
  85 dnl allow cross compiling
  86 AC_LIBTOOL_WIN32_DLL
  87 AC_PROG_LIBTOOL
  88
  89 AC_CONFIG_HEADERS(src/config.h)
  90 AC_CONFIG_FILES(aubio.pc)
  91
  92 AM_CONDITIONAL(MINGW, false)
  93 AM_CONDITIONAL(DARWIN, false)
  94 case "${host}" in
  95 *mingw* | *cygwin*)
  96   mingw32_support="yes"
  97   AC_CHECK_HEADER(windows.h)
  98   AM_CONDITIONAL(MINGW, true)
  99   LDFLAGS="$LDFLAGS -no-undefined"
 100   ;;
 101 *darwin* | *rhapsody* | *macosx*)
 102   AC_ISC_POSIX
 103   AM_CONDITIONAL(DARWIN, true)
 104   ;;
 105 *)
 106   AC_ISC_POSIX
 107   ;;
 108 esac
 109
 110 dnl Check for required libraries
 111 AC_CHECK_LIB(pthread, pthread_create)
 112
 113 dnl Check for header files
 114 AC_CHECK_HEADERS([string.h stdlib.h stdio.h math.h errno.h stdarg.h unistd.h signal.h],,)
 115 AC_CHECK_HEADERS(fftw3.h,,AC_MSG_ERROR([Ouch! missing fftw3.h header]))
 116 AC_ARG_ENABLE(complex,
 117   AC_HELP_STRING([--enable-complex],[compile with complex.h [[default=auto]]]),
 118   [with_complex=$enableval],
 119   with_complex="yes")
 120 if test "$with_complex" = "yes"; then
 121   AC_CHECK_HEADERS(complex.h,,AC_MSG_WARN([Ouch! missing complex.h header]))
 122 fi
 123
 124 dnl Check for __VAR_ARGS__ support
 125 AC_CACHE_CHECK(for C99 __VA_ARGS__ macro,
 126     ac_cv_varargs_macros,
 127 AC_TRY_COMPILE([
 128   #include <stdio.h>
 129   #define AUBIO_ERR(...)                       fprintf(stderr, __VA_ARGS__)
 130 ],
 131 [
 132   AUBIO_ERR("%s\n", "ERR");
 133 ],
 134         ac_cv_varargs_macros=yes,
 135         ac_cv_varargs_macros=no)
 136 )
 137 if test "$ac_cv_varargs_macros" = "yes"; then
 138     AC_DEFINE(HAVE_C99_VARARGS_MACROS, 1,
 139             [Defined when c99 style varargs macros are supported])
 140 fi
 141
 142 dnl Check for pkg-config
 143 AC_PATH_PROG(PKG_CONFIG,pkg-config,no)
 144
 145 PKG_CHECK_MODULES(SNDLIB,     sndfile >= 1.0.4,       SNDLIB_SUPPORT=1)
 146 PKG_CHECK_MODULES(SAMPLERATE, samplerate  >= 0.0.15,  SAMPLERATE_SUPPORT=1)
 147
 148 if test "${SNDLIB_SUPPORT}" = "1"; then
 149   AC_DEFINE(SNDLIB_SUPPORT,1,[Define to enable libsndfile support])
 150 fi
 151
 152 dnl Check for fftw3 (required)
 153 AC_ARG_ENABLE(fftw3f,
 154   AC_HELP_STRING([--enable-fftw3f],[compile with fftw3f [[default=auto]]]),
 155   [with_fftw3f=$enableval],
 156   with_fftw3f="yes")
 157 if test "$with_fftw3f" = "yes"; then
 158   PKG_CHECK_MODULES(FFTWLIB,    fftw3f >= 3.0.0,     FFTW3F_SUPPORT=1, FFTW3F_SUPPORT=0)
 159 else
 160   PKG_CHECK_MODULES(FFTWLIB,    fftw3  >= 3.0.0,     FFTW3_SUPPORT=1)
 161 fi
 162 if test "${FFTW3F_SUPPORT}" = "0"; then
 163   PKG_CHECK_MODULES(FFTWLIB,    fftw3  >= 3.0.0,     FFTW3_SUPPORT=1)
 164 fi
 165 if test "${FFTW3_SUPPORT}" = "1"; then
 166   AC_DEFINE(FFTW3_SUPPORT,1,[Define to enable fftw3 support])
 167 fi
 168 if test "${FFTW3F_SUPPORT}" = "1"; then
 169   AC_DEFINE(FFTW3F_SUPPORT,1,[Define to enable fftw3f support])
 170 fi
 171
 172 dnl Enable jack support (auto)
 173 AC_ARG_ENABLE(jack,
 174   AC_HELP_STRING([--enable-jack],[compile with jack [[default=auto]]]),
 175   [with_jack=$enableval],
 176   with_jack="yes")
 177 if test "$with_jack" = "yes"
 178 then
 179   PKG_CHECK_MODULES(JACK,       jack  >= 0.15.0,     JACK_SUPPORT=1, JACK_SUPPORT=0)
 180   if test "${JACK_SUPPORT}" = "1"; then
 181     AC_DEFINE(JACK_SUPPORT,1,[Define to enable jack support])
 182   fi
 183 fi
 184
 185 dnl Enable alsa support (auto)
 186 AC_ARG_ENABLE(alsa,
 187   AC_HELP_STRING([--enable-alsa],[compile with alsa [[default=auto]]]),
 188   [with_alsa=$enableval],
 189   with_alsa="yes")
 190 if test "$with_alsa" = "yes"
 191 then
 192   if test "$with_jack" = "yes"
 193   then
 194     PKG_CHECK_MODULES(ALSA,      alsa >= 0.0.9,      ALSA_SUPPORT=1, ALSA_SUPPORT=0)
 195     if test "${ALSA_SUPPORT}" = "1"; then
 196       AC_DEFINE(ALSA_SUPPORT,1,[Define to enable alsa support])
 197     fi
 198   else
 199     AC_MSG_WARN([Disabling alsa as jack was not found])
 200   fi
 201 fi
 202
 203 dnl Enable lash support
 204 AC_ARG_ENABLE(lash,
 205   AC_HELP_STRING([--enable-lash],[compile with lash [[default=auto]]]),
 206   [with_lash=$enableval],
 207   with_lash="yes")
 208 if test "$with_lash" = "yes"
 209 then
 210   PKG_CHECK_MODULES(LASH,   lash-1.0 >= 0.5.0,   LASH_SUPPORT=1, LASH_SUPPORT=0)
 211   if test "${LASH_SUPPORT}" = "1"; then
 212     LASH_CFLAGS+="-DLASH_SUPPORT"
 213   fi
 214 fi
 215
 216 dnl Enable unit tests
 217 AC_ARG_ENABLE(testprogs,
 218   AC_HELP_STRING([--enable-testprogs],[compile test programs [[default=no]]]),
 219   [with_testprogs=$enableval],
 220   with_testprogs="no")
 221 AM_CONDITIONAL(COMPILE_TESTS,test "${with_testprogs}" != "no")
 222
 223 AC_SUBST(AUBIO_CFLAGS)
 224
 225 dnl Check for swig and python
 226 dnl should check for swig version and python headers
 227 AC_PATH_PROG(SWIG,swig,no)
 228 AM_CONDITIONAL(SWIGFOUND, test "${SWIG}" != "no")
 229 AM_PATH_PYTHON
 230 AM_CONDITIONAL(PYTHONFOUND, test "${PYTHON}" != "no")
 231
 232 dnl Check for docbook-to-man
 233 AC_PATH_PROG(DOCBOOK_TO_MAN,docbook-to-man,no)
 234 AM_CONDITIONAL(DOCBOOKFOUND, test "${DOCBOOK_TO_MAN}" != "no")
 235
 236 dnl Check for Puredata
 237 AC_CHECK_HEADER(m_pd.h,PUREDATA=y,AC_MSG_WARN([Puredata header not found.]))
 238 AM_CONDITIONAL(PUREDATAFOUND, test "${PUREDATA}" = "y")
 239
 240 dnl Check for Java
 241 AC_CHECK_HEADER(jni.h,JAVAHEADERS=y,AC_MSG_WARN([Java header jni.h not found.]))
 242 AM_CONDITIONAL(JAVAFOUND, test "${JAVAHEADERS}" = "y")
 243
 244 dnl Create Makefiles
 245 AC_OUTPUT([
 246     Makefile
 247     src/Makefile
 248     ext/Makefile
 249     cpp/Makefile
 250     examples/Makefile
 251     tests/Makefile
 252     tests/src/Makefile
 253     tests/cpp/Makefile
 254     sounds/Makefile
 255     swig/Makefile
 256     python/Makefile
 257     python/aubio/Makefile
 258     java/Makefile
 259     java/aubio/Makefile
 260     plugins/Makefile
 261     plugins/audacity/Makefile
 262     plugins/audacity/plug-ins/Makefile
 263     plugins/wavesurfer/Makefile
 264     plugins/puredata/Makefile
 265     doc/Makefile
 266   ])
 267
 268 dnl Print summary
 269 echo
 270 echo "**************************************************************"
 271 echo "Summary:"
 272 if test "${FFTW3F_SUPPORT}" = "1"; then
 273   echo "Fftw3:                   yes (using fftw3f)"
 274 else
 275 if test "${FFTW3_SUPPORT}" = "1"; then
 276   echo "Fftw3:                   yes (not using fftw3f)"
 277 else
 278   echo "Fftw3:                   no (that should not happen)"
 279 fi
 280 fi
 281 if test "${SNDLIB_SUPPORT}" = "1"; then
 282   echo "Libsndfile:              yes"
 283 else
 284   echo "Libsndfile:              no"
 285 fi
 286 if test "${SAMPLERATE_SUPPORT}" = "1"; then
 287   echo "Libsamplerate:           yes"
 288 else
 289   echo "Libsamplerate:           no"
 290 fi
 291 if test "${JACK_SUPPORT}" = "1"; then
 292   echo "JACK:                    yes"
 293 else
 294   echo "JACK:                    no"
 295 fi
 296 if test "${ALSA_SUPPORT}" = "1"; then
 297   echo "ALSA midi:               yes"
 298 else
 299   echo "ALSA midi:               no"
 300 fi
 301 if test "${LASH_SUPPORT}" = "1"; then
 302   echo "Lash:                    yes"
 303 else
 304   echo "Lash:                    no"
 305 fi
 306 if test "${PUREDATA}" = "y"; then
 307   echo "PureData:                yes"
 308 else
 309   echo "PureData:                no"
 310 fi
 311 echo "**************************************************************"
 312 echo Configuration completed successfully. Type \'make\' to build ${PACKAGE}