configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Init autoconf
   4 AC_INIT(src/aubio.h)
   5
   6 dnl Package name and version
   7 PACKAGE=aubio
   8 . $srcdir/VERSION
   9 AUBIO_VERSION=${AUBIO_MAJOR_VERSION}.${AUBIO_MINOR_VERSION}.${AUBIO_PATCH_VERSION}${AUBIO_VERSION_STATUS}
  10 VERSION=${AUBIO_VERSION}
  11
  12 dnl Shared library version
  13 SHARED_VERSION_INFO=${LIBAUBIO_LT_CUR}:${LIBAUBIO_LT_REV}:${LIBAUBIO_LT_AGE}
  14 AC_SUBST(SHARED_VERSION_INFO)
  15
  16 dnl Init automake
  17 AM_INIT_AUTOMAKE(${PACKAGE}, ${VERSION})
  18
  19 dnl Maintainer mode
  20 AM_MAINTAINER_MODE
  21
  22 dnl Guess the host
  23 AC_CANONICAL_HOST
  24
  25 dnl Check for programs
  26 AC_PROG_CC
  27 AM_PROG_CC_C_O dnl compiling with per-target flag
  28 if test "$ac_cv_prog_cc" = "no" ; then
  29    AC_MSG_ERROR([*** No C compiler found !])
  30 fi
  31 AC_PROG_INSTALL
  32
  33 AUBIO_CFLAGS=
  34
  35 dnl Enable debugging (no)
  36 AC_ARG_ENABLE(debug,
  37   [  --enable-debug[[=value]]  compile with debug [[default=no]]],
  38   with_debug="yes",
  39   with_debug="no")
  40 if test "$with_debug" = "yes"
  41 then
  42   AC_DEFINE(DEBUG,1,[Define to enable debug])
  43   AUBIO_CFLAGS="$AUBIO_CFLAGS -g"
  44 fi
  45
  46 dnl Enable full warnings (yes)
  47 AC_ARG_ENABLE(warnings,
  48   [  --enable-warnings[[=value]] compile with all gcc warnings [[default=yes]]],
  49   with_warnme="no",
  50   with_warnme="yes")
  51 if test "$with_warnme" = "yes"
  52 then
  53   dnl Check for -Wextra support to allow compilation on gcc <= 3.4
  54   AC_CACHE_CHECK([for -Wextra option to $CC], ac_cv_cc_wextra,
  55   [old_CFLAGS="$CFLAGS"
  56   CFLAGS="$CFLAGS -Wextra"
  57   AC_COMPILE_IFELSE([void foo (void) {}],
  58           ac_cv_cc_wextra=yes, ac_cv_cc_wextra=no)
  59   CFLAGS="$old_CFLAGS"
  60   ])
  61   if test "$ac_cv_cc_wextra" = "yes"
  62   then
  63     AUBIO_CFLAGS="$AUBIO_CFLAGS -Wall -Wextra"
  64   else
  65     AUBIO_CFLAGS="$AUBIO_CFLAGS -Wall"
  66   fi
  67 fi
  68
  69 AC_ARG_ENABLE(errorfail,
  70   [  --enable-errorfail[[=value]]  fail on compilation warnings [[default=no]]],
  71   AUBIO_CFLAGS="$AUBIO_CFLAGS -Werror -Wmissing-prototypes -Wmissing-declarations -Wno-unused-parameter",
  72   with_warnme="no")
  73
  74 dnl Check for libtool
  75 AC_LIBTOOL_DLOPEN
  76 dnl AC_DISABLE_STATIC
  77 AC_PROG_LIBTOOL
  78
  79 AC_CONFIG_HEADERS(src/config.h)
  80 AC_CONFIG_FILES(aubio.pc)
  81
  82 AM_CONDITIONAL(MINGW, false)
  83 AM_CONDITIONAL(DARWIN, false)
  84 case "${build_os}" in
  85 *mingw* | *cygwin*)
  86   mingw32_support="yes"
  87   AC_CHECK_HEADER(windows.h)
  88   AM_CONDITIONAL(MINGW, true)
  89   LDFLAGS="$LDFLAGS -no-undefined"
  90   ;;
  91 *darwin* | *rhapsody* | *macosx*)
  92   dnl on macosx, cosf went to -lmx
  93   LDFLAGS="$LDFLAGS -lmx"
  94   dnl as long double doesn't sit well with -Wall -Werror
  95   AUBIO_CFLAGS="$AUBIO_CFLAGS -Wno-long-double"
  96   dnl Workaround darwin autoconf bug
  97   CPPFLAGS="$CPPFLAGS -I${prefix}/include"
  98   AC_ISC_POSIX
  99   AM_CONDITIONAL(DARWIN, true)
 100   ;;
 101 *)
 102   AC_ISC_POSIX
 103   ;;
 104 esac
 105
 106 dnl Check for required libraries
 107 AC_CHECK_LIB(pthread, pthread_create)
 108
 109 dnl Check for header files
 110 AC_HEADER_STDC
 111 AC_CHECK_HEADERS([string.h stdlib.h stdio.h math.h errno.h stdarg.h unistd.h signal.h],,)
 112 AC_CHECK_HEADERS(fftw3.h,,AC_MSG_ERROR([Ouch! missing fftw3.h header]))
 113 AC_ARG_ENABLE(complex,
 114   AC_HELP_STRING([--enable-complex],[compile with complex.h [[default=auto]]]),
 115   [with_complex=$enableval],
 116   with_complex="yes")
 117 if test "$with_complex" = "yes"; then
 118   AC_CHECK_HEADERS(complex.h,,AC_MSG_WARN([Ouch! missing complex.h header]))
 119 fi
 120
 121 dnl Check for __VAR_ARGS__ support
 122 AC_CACHE_CHECK(for C99 __VA_ARGS__ macro,
 123     ac_cv_varargs_macros,
 124 AC_TRY_COMPILE([
 125   #include <stdio.h>
 126   #define AUBIO_ERR(...)                       fprintf(stderr, __VA_ARGS__)
 127 ],
 128 [
 129   AUBIO_ERR("%s\n", "ERR");
 130 ],
 131         ac_cv_varargs_macros=yes,
 132         ac_cv_varargs_macros=no)
 133 )
 134 if test "$ac_cv_varargs_macros" = "yes"; then
 135     AC_DEFINE(HAVE_C99_VARARGS_MACROS, 1,
 136             [Defined when c99 style varargs macros are supported])
 137 fi
 138
 139 dnl Check for pkg-config
 140 AC_PATH_PROG(PKG_CONFIG,pkg-config,no)
 141
 142 PKG_CHECK_MODULES(SNDLIB,     sndfile >= 1.0.4,       SNDLIB_SUPPORT=1)
 143 PKG_CHECK_MODULES(SAMPLERATE, samplerate  >= 0.0.15,  SAMPLERATE_SUPPORT=1)
 144
 145 if test "${SNDLIB_SUPPORT}" = "1"; then
 146   AC_DEFINE(SNDLIB_SUPPORT,1,[Define to enable libsndfile support])
 147 fi
 148
 149 dnl Check for fftw3 (required)
 150 AC_ARG_ENABLE(fftw3f,
 151   AC_HELP_STRING([--enable-fftw3f],[compile with fftw3f [[default=auto]]]),
 152   [with_fftw3f=$enableval],
 153   with_fftw3f="yes")
 154 if test "$with_fftw3f" = "yes"; then
 155   PKG_CHECK_MODULES(FFTWLIB,    fftw3f >= 3.0.0,     FFTW3F_SUPPORT=1, FFTW3F_SUPPORT=0)
 156 else
 157   PKG_CHECK_MODULES(FFTWLIB,    fftw3  >= 3.0.0,     FFTW3_SUPPORT=1)
 158 fi
 159 if test "${FFTW3F_SUPPORT}" = "0"; then
 160   PKG_CHECK_MODULES(FFTWLIB,    fftw3  >= 3.0.0,     FFTW3_SUPPORT=1)
 161 fi
 162 if test "${FFTW3_SUPPORT}" = "1"; then
 163   AC_DEFINE(FFTW3_SUPPORT,1,[Define to enable fftw3 support])
 164 fi
 165 if test "${FFTW3F_SUPPORT}" = "1"; then
 166   AC_DEFINE(FFTW3F_SUPPORT,1,[Define to enable fftw3f support])
 167 fi
 168
 169 dnl Enable jack support (auto)
 170 AC_ARG_ENABLE(jack,
 171   AC_HELP_STRING([--enable-jack],[compile with jack [[default=auto]]]),
 172   [with_jack=$enableval],
 173   with_jack="yes")
 174 if test "$with_jack" = "yes"
 175 then
 176   PKG_CHECK_MODULES(JACK,       jack  >= 0.15.0,     JACK_SUPPORT=1, JACK_SUPPORT=0)
 177   if test "${JACK_SUPPORT}" = "1"; then
 178     AC_DEFINE(JACK_SUPPORT,1,[Define to enable jack support])
 179   fi
 180 fi
 181
 182 dnl Enable alsa support (auto)
 183 AC_ARG_ENABLE(alsa,
 184   AC_HELP_STRING([--enable-alsa],[compile with alsa [[default=auto]]]),
 185   [with_alsa=$enableval],
 186   with_alsa="yes")
 187 if test "$with_alsa" = "yes"
 188 then
 189   if test "$with_jack" = "yes"
 190   then
 191     PKG_CHECK_MODULES(ALSA,      alsa >= 0.0.9,      ALSA_SUPPORT=1, ALSA_SUPPORT=0)
 192     if test "${ALSA_SUPPORT}" = "1"; then
 193       AC_DEFINE(ALSA_SUPPORT,1,[Define to enable alsa support])
 194     fi
 195   else
 196     AC_MSG_WARN([Disabling alsa as jack was not found])
 197   fi
 198 fi
 199
 200 dnl Enable lash support
 201 AC_ARG_ENABLE(lash,
 202   AC_HELP_STRING([--enable-lash],[compile with lash [[default=auto]]]),
 203   [with_lash=$enableval],
 204   with_lash="yes")
 205 if test "$with_lash" = "yes"
 206 then
 207   PKG_CHECK_MODULES(LASH,   lash-1.0 >= 0.5.0,   LASH_SUPPORT=1, LASH_SUPPORT=0)
 208   if test "${LASH_SUPPORT}" = "1"; then
 209     LASH_CFLAGS+="-DLASH_SUPPORT"
 210   fi
 211 fi
 212
 213 dnl Enable unit tests
 214 AC_ARG_ENABLE(testprogs,
 215   AC_HELP_STRING([--enable-testprogs],[compile test programs [[default=no]]]),
 216   [with_testprogs=$enableval],
 217   with_testprogs="no")
 218 AM_CONDITIONAL(COMPILE_TESTS,test "${with_testprogs}" != "no")
 219
 220 AC_SUBST(AUBIO_CFLAGS)
 221
 222 dnl Check for swig and python
 223 dnl should check for swig version and python headers
 224 AC_PATH_PROG(SWIG,swig,no)
 225 AM_CONDITIONAL(SWIGFOUND, test "${SWIG}" != "no")
 226 AM_PATH_PYTHON
 227 AM_CONDITIONAL(PYTHONFOUND, test "${PYTHON}" != "no")
 228
 229 dnl Check for docbook-to-man
 230 AC_PATH_PROG(DOCBOOK_TO_MAN,docbook-to-man,no)
 231 AM_CONDITIONAL(DOCBOOKFOUND, test "${DOCBOOK_TO_MAN}" != "no")
 232
 233 dnl Check for Puredata
 234 AC_CHECK_HEADER(m_pd.h,PUREDATA=y,AC_MSG_WARN([Puredata header not found.]))
 235 AM_CONDITIONAL(PUREDATAFOUND, test "${PUREDATA}" = "y")
 236
 237 dnl Create Makefiles
 238 AC_OUTPUT([
 239     Makefile
 240     src/Makefile
 241     ext/Makefile
 242     examples/Makefile
 243     tests/Makefile
 244     tests/src/Makefile
 245     sounds/Makefile
 246     swig/Makefile
 247     python/Makefile
 248     python/aubio/Makefile
 249     plugins/Makefile
 250     plugins/audacity/Makefile
 251     plugins/audacity/plug-ins/Makefile
 252     plugins/wavesurfer/Makefile
 253     plugins/puredata/Makefile
 254     doc/Makefile
 255   ])
 256
 257 dnl Print summary
 258 echo
 259 echo "**************************************************************"
 260 echo "Summary:"
 261 if test "${FFTW3F_SUPPORT}" = "1"; then
 262   echo "Fftw3:                   yes (using fftw3f)"
 263 else
 264 if test "${FFTW3_SUPPORT}" = "1"; then
 265   echo "Fftw3:                   yes (not using fftw3f)"
 266 else
 267   echo "Fftw3:                   no (that should not happen)"
 268 fi
 269 fi
 270 if test "${SNDLIB_SUPPORT}" = "1"; then
 271   echo "Libsndfile:              yes"
 272 else
 273   echo "Libsndfile:              no"
 274 fi
 275 if test "${SAMPLERATE_SUPPORT}" = "1"; then
 276   echo "Libsamplerate:           yes"
 277 else
 278   echo "Libsamplerate:           no"
 279 fi
 280 if test "${JACK_SUPPORT}" = "1"; then
 281   echo "JACK:                    yes"
 282 else
 283   echo "JACK:                    no"
 284 fi
 285 if test "${ALSA_SUPPORT}" = "1"; then
 286   echo "ALSA midi:               yes"
 287 else
 288   echo "ALSA midi:               no"
 289 fi
 290 if test "${LASH_SUPPORT}" = "1"; then
 291   echo "Lash:                    yes"
 292 else
 293   echo "Lash:                    no"
 294 fi
 295 if test "${PUREDATA}" = "y"; then
 296   echo "PureData:                yes"
 297 else
 298   echo "PureData:                no"
 299 fi
 300 echo "**************************************************************"
 301 echo Configuration completed successfully. Type \'make\' to build ${PACKAGE}