configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl Init autoconf
   4 AC_INIT(src/aubio.h)
   5
   6 dnl Package name and version
   7 PACKAGE=aubio
   8 . $srcdir/VERSION
   9 AUBIO_VERSION=${AUBIO_MAJOR_VERSION}.${AUBIO_MINOR_VERSION}.${AUBIO_PATCH_VERSION}${AUBIO_VERSION_STATUS}
  10 VERSION=${AUBIO_VERSION}
  11
  12 dnl Shared library version
  13 SHARED_VERSION_INFO=${LIBAUBIO_LT_CUR}:${LIBAUBIO_LT_REV}:${LIBAUBIO_LT_AGE}
  14 AC_SUBST(SHARED_VERSION_INFO)
  15
  16 dnl Init automake
  17 AM_INIT_AUTOMAKE(${PACKAGE}, ${VERSION})
  18
  19 dnl Maintainer mode
  20 AM_MAINTAINER_MODE
  21
  22 dnl Guess the host
  23 AC_CANONICAL_HOST
  24
  25 dnl Check for programs
  26 AC_PROG_CC
  27 AM_PROG_CC_C_O dnl compiling with per-target flag
  28 if test "$ac_cv_prog_cc" = "no" ; then
  29    AC_MSG_ERROR([*** No C compiler found !])
  30 fi
  31 AC_PROG_INSTALL
  32
  33 AUBIO_CFLAGS=
  34
  35 dnl Enable debugging (no)
  36 AC_ARG_ENABLE(debug,
  37   AC_HELP_STRING([--enable-debug],[compile in debug mode [[default=no]]]),
  38   with_debug="yes",
  39   with_debug="no")
  40 if test "$with_debug" = "yes"
  41 then
  42   AC_DEFINE(DEBUG,1,[Define to enable debug])
  43   AUBIO_CFLAGS="$AUBIO_CFLAGS -g"
  44 fi
  45
  46 dnl Enable full warnings (yes)
  47 AC_ARG_ENABLE(warnings,
  48   AC_HELP_STRING([--enable-warnings],[compile with all gcc warnings [[default=yes]]]),
  49   with_warnme="no",
  50   with_warnme="yes")
  51 if test "$with_warnme" = "yes"
  52 then
  53   dnl Check for -Wextra support to allow compilation on gcc <= 3.4
  54   AC_CACHE_CHECK([for -Wextra option to $CC], ac_cv_cc_wextra,
  55   [old_CFLAGS="$CFLAGS"
  56   CFLAGS="$CFLAGS -Wextra"
  57   AC_COMPILE_IFELSE([void foo (void) {}],
  58           ac_cv_cc_wextra=yes, ac_cv_cc_wextra=no)
  59   CFLAGS="$old_CFLAGS"
  60   ])
  61   if test "$ac_cv_cc_wextra" = "yes"
  62   then
  63     AUBIO_CFLAGS="$AUBIO_CFLAGS -Wall -Wextra"
  64   else
  65     AUBIO_CFLAGS="$AUBIO_CFLAGS -Wall"
  66   fi
  67 fi
  68
  69 dnl fail on compilation warnings
  70 AC_ARG_ENABLE(errorfail,
  71   AC_HELP_STRING([--enable-errorfail],[fail on compilation warnings [[default=no]]]),
  72   AUBIO_CFLAGS="$AUBIO_CFLAGS -Werror -Wmissing-prototypes -Wmissing-declarations -Wno-unused-parameter",
  73   with_errorfail="no")
  74
  75 dnl add gcov/lcov profiling and coverage flags
  76 AC_ARG_ENABLE(lcov,
  77   AC_HELP_STRING([--enable-lcov],[compile with gcov/lcov profiling flags [[default=no]]]),
  78   AUBIO_CFLAGS="$AUBIO_CFLAGS -fprofile-arcs -ftest-coverage",
  79   with_lcov="no")
  80
  81 dnl Check for libtool
  82 AC_LIBTOOL_DLOPEN
  83 dnl AC_DISABLE_STATIC
  84 dnl allow cross compiling
  85 AC_LIBTOOL_WIN32_DLL
  86 AC_PROG_LIBTOOL
  87
  88 AC_CONFIG_HEADERS(src/config.h)
  89 AC_CONFIG_FILES(aubio.pc)
  90
  91 AM_CONDITIONAL(MINGW, false)
  92 AM_CONDITIONAL(DARWIN, false)
  93 case "${host_os}" in
  94 *mingw* | *cygwin*)
  95   mingw32_support="yes"
  96   AC_CHECK_HEADER(windows.h)
  97   AM_CONDITIONAL(MINGW, true)
  98   LDFLAGS="$LDFLAGS -no-undefined"
  99   ;;
 100 *darwin* | *rhapsody* | *macosx*)
 101   dnl on macosx, cosf went to -lmx
 102   LDFLAGS="$LDFLAGS -lmx"
 103   dnl as long double doesn't sit well with -Wall -Werror
 104   AUBIO_CFLAGS="$AUBIO_CFLAGS -Wno-long-double"
 105   dnl Workaround darwin autoconf bug
 106   CPPFLAGS="$CPPFLAGS -I${prefix}/include"
 107   AC_ISC_POSIX
 108   AM_CONDITIONAL(DARWIN, true)
 109   ;;
 110 *)
 111   AC_ISC_POSIX
 112   ;;
 113 esac
 114
 115 dnl Check for required libraries
 116 AC_CHECK_LIB(pthread, pthread_create)
 117
 118 dnl Check for header files
 119 AC_HEADER_STDC
 120 AC_CHECK_HEADERS([string.h stdlib.h stdio.h math.h errno.h stdarg.h unistd.h signal.h],,)
 121 AC_CHECK_HEADERS(fftw3.h,,AC_MSG_ERROR([Ouch! missing fftw3.h header]))
 122 AC_ARG_ENABLE(complex,
 123   AC_HELP_STRING([--enable-complex],[compile with complex.h [[default=auto]]]),
 124   [with_complex=$enableval],
 125   with_complex="yes")
 126 if test "$with_complex" = "yes"; then
 127   AC_CHECK_HEADERS(complex.h,,AC_MSG_WARN([Ouch! missing complex.h header]))
 128 fi
 129
 130 dnl Check for __VAR_ARGS__ support
 131 AC_CACHE_CHECK(for C99 __VA_ARGS__ macro,
 132     ac_cv_varargs_macros,
 133 AC_TRY_COMPILE([
 134   #include <stdio.h>
 135   #define AUBIO_ERR(...)                       fprintf(stderr, __VA_ARGS__)
 136 ],
 137 [
 138   AUBIO_ERR("%s\n", "ERR");
 139 ],
 140         ac_cv_varargs_macros=yes,
 141         ac_cv_varargs_macros=no)
 142 )
 143 if test "$ac_cv_varargs_macros" = "yes"; then
 144     AC_DEFINE(HAVE_C99_VARARGS_MACROS, 1,
 145             [Defined when c99 style varargs macros are supported])
 146 fi
 147
 148 dnl Check for pkg-config
 149 AC_PATH_PROG(PKG_CONFIG,pkg-config,no)
 150
 151 PKG_CHECK_MODULES(SNDLIB,     sndfile >= 1.0.4,       SNDLIB_SUPPORT=1)
 152 PKG_CHECK_MODULES(SAMPLERATE, samplerate  >= 0.0.15,  SAMPLERATE_SUPPORT=1)
 153
 154 if test "${SNDLIB_SUPPORT}" = "1"; then
 155   AC_DEFINE(SNDLIB_SUPPORT,1,[Define to enable libsndfile support])
 156 fi
 157
 158 dnl Check for fftw3 (required)
 159 AC_ARG_ENABLE(fftw3f,
 160   AC_HELP_STRING([--enable-fftw3f],[compile with fftw3f [[default=auto]]]),
 161   [with_fftw3f=$enableval],
 162   with_fftw3f="yes")
 163 if test "$with_fftw3f" = "yes"; then
 164   PKG_CHECK_MODULES(FFTWLIB,    fftw3f >= 3.0.0,     FFTW3F_SUPPORT=1, FFTW3F_SUPPORT=0)
 165 else
 166   PKG_CHECK_MODULES(FFTWLIB,    fftw3  >= 3.0.0,     FFTW3_SUPPORT=1)
 167 fi
 168 if test "${FFTW3F_SUPPORT}" = "0"; then
 169   PKG_CHECK_MODULES(FFTWLIB,    fftw3  >= 3.0.0,     FFTW3_SUPPORT=1)
 170 fi
 171 if test "${FFTW3_SUPPORT}" = "1"; then
 172   AC_DEFINE(FFTW3_SUPPORT,1,[Define to enable fftw3 support])
 173 fi
 174 if test "${FFTW3F_SUPPORT}" = "1"; then
 175   AC_DEFINE(FFTW3F_SUPPORT,1,[Define to enable fftw3f support])
 176 fi
 177
 178 dnl Enable jack support (auto)
 179 AC_ARG_ENABLE(jack,
 180   AC_HELP_STRING([--enable-jack],[compile with jack [[default=auto]]]),
 181   [with_jack=$enableval],
 182   with_jack="yes")
 183 if test "$with_jack" = "yes"
 184 then
 185   PKG_CHECK_MODULES(JACK,       jack  >= 0.15.0,     JACK_SUPPORT=1, JACK_SUPPORT=0)
 186   if test "${JACK_SUPPORT}" = "1"; then
 187     AC_DEFINE(JACK_SUPPORT,1,[Define to enable jack support])
 188   fi
 189 fi
 190
 191 dnl Enable alsa support (auto)
 192 AC_ARG_ENABLE(alsa,
 193   AC_HELP_STRING([--enable-alsa],[compile with alsa [[default=auto]]]),
 194   [with_alsa=$enableval],
 195   with_alsa="yes")
 196 if test "$with_alsa" = "yes"
 197 then
 198   if test "$with_jack" = "yes"
 199   then
 200     PKG_CHECK_MODULES(ALSA,      alsa >= 0.0.9,      ALSA_SUPPORT=1, ALSA_SUPPORT=0)
 201     if test "${ALSA_SUPPORT}" = "1"; then
 202       AC_DEFINE(ALSA_SUPPORT,1,[Define to enable alsa support])
 203     fi
 204   else
 205     AC_MSG_WARN([Disabling alsa as jack was not found])
 206   fi
 207 fi
 208
 209 dnl Enable lash support
 210 AC_ARG_ENABLE(lash,
 211   AC_HELP_STRING([--enable-lash],[compile with lash [[default=auto]]]),
 212   [with_lash=$enableval],
 213   with_lash="yes")
 214 if test "$with_lash" = "yes"
 215 then
 216   PKG_CHECK_MODULES(LASH,   lash-1.0 >= 0.5.0,   LASH_SUPPORT=1, LASH_SUPPORT=0)
 217   if test "${LASH_SUPPORT}" = "1"; then
 218     LASH_CFLAGS+="-DLASH_SUPPORT"
 219   fi
 220 fi
 221
 222 dnl Enable unit tests
 223 AC_ARG_ENABLE(testprogs,
 224   AC_HELP_STRING([--enable-testprogs],[compile test programs [[default=no]]]),
 225   [with_testprogs=$enableval],
 226   with_testprogs="no")
 227 AM_CONDITIONAL(COMPILE_TESTS,test "${with_testprogs}" != "no")
 228
 229 AC_SUBST(AUBIO_CFLAGS)
 230
 231 dnl Check for swig and python
 232 dnl should check for swig version and python headers
 233 AC_PATH_PROG(SWIG,swig,no)
 234 AM_CONDITIONAL(SWIGFOUND, test "${SWIG}" != "no")
 235 AM_PATH_PYTHON
 236 AM_CONDITIONAL(PYTHONFOUND, test "${PYTHON}" != "no")
 237
 238 dnl Check for docbook-to-man
 239 AC_PATH_PROG(DOCBOOK_TO_MAN,docbook-to-man,no)
 240 AM_CONDITIONAL(DOCBOOKFOUND, test "${DOCBOOK_TO_MAN}" != "no")
 241
 242 dnl Check for Puredata
 243 AC_CHECK_HEADER(m_pd.h,PUREDATA=y,AC_MSG_WARN([Puredata header not found.]))
 244 AM_CONDITIONAL(PUREDATAFOUND, test "${PUREDATA}" = "y")
 245
 246 dnl Create Makefiles
 247 AC_OUTPUT([
 248     Makefile
 249     src/Makefile
 250     ext/Makefile
 251     examples/Makefile
 252     tests/Makefile
 253     tests/src/Makefile
 254     sounds/Makefile
 255     swig/Makefile
 256     python/Makefile
 257     python/aubio/Makefile
 258     plugins/Makefile
 259     plugins/audacity/Makefile
 260     plugins/audacity/plug-ins/Makefile
 261     plugins/wavesurfer/Makefile
 262     plugins/puredata/Makefile
 263     doc/Makefile
 264   ])
 265
 266 dnl Print summary
 267 echo
 268 echo "**************************************************************"
 269 echo "Summary:"
 270 if test "${FFTW3F_SUPPORT}" = "1"; then
 271   echo "Fftw3:                   yes (using fftw3f)"
 272 else
 273 if test "${FFTW3_SUPPORT}" = "1"; then
 274   echo "Fftw3:                   yes (not using fftw3f)"
 275 else
 276   echo "Fftw3:                   no (that should not happen)"
 277 fi
 278 fi
 279 if test "${SNDLIB_SUPPORT}" = "1"; then
 280   echo "Libsndfile:              yes"
 281 else
 282   echo "Libsndfile:              no"
 283 fi
 284 if test "${SAMPLERATE_SUPPORT}" = "1"; then
 285   echo "Libsamplerate:           yes"
 286 else
 287   echo "Libsamplerate:           no"
 288 fi
 289 if test "${JACK_SUPPORT}" = "1"; then
 290   echo "JACK:                    yes"
 291 else
 292   echo "JACK:                    no"
 293 fi
 294 if test "${ALSA_SUPPORT}" = "1"; then
 295   echo "ALSA midi:               yes"
 296 else
 297   echo "ALSA midi:               no"
 298 fi
 299 if test "${LASH_SUPPORT}" = "1"; then
 300   echo "Lash:                    yes"
 301 else
 302   echo "Lash:                    no"
 303 fi
 304 if test "${PUREDATA}" = "y"; then
 305   echo "PureData:                yes"
 306 else
 307   echo "PureData:                no"
 308 fi
 309 echo "**************************************************************"
 310 echo Configuration completed successfully. Type \'make\' to build ${PACKAGE}